«
»

Learning a new programming language

It’s common sense in the programming circle that programmers should make an effort to learn a new language every year. Some make it their New Year’s resolution, some just do it for the fun of it, others do it to enrich their experience and their CV. So, today, I decided to grab a new language and stick with it until I MASTER the damn thing. I only had a requirement before choosing it: it had to be fun!

So, what language did I choose? None other than LOLCode.

I know what’s going through your mind now. “Why the eff is this guy even thinking about learning a new language?”, “useless”, or even “OH HAY I CAN HAS CODEZ?”. There’s a reason for that.

I tend to browse lolcats whenever I need a bit of extra motivation, romance, feeding or even inspiration. So, whenever I look at bits of code that read:

  1. HAI
  2. CAN HAS STDIO?
  3. VISIBLE "HAI WORLD!"
  4. KTHXBYE

or even

  1. ON CATURDAY
  2.  IM IN YR BED
  3.   I IZ SLEEPIN!!10
  4.   VISIBLE "Z!"
  5.  KTHX
  6. KTHXBYE

I can’t stop thinking that it’s PURE GENIUS (right before bursting into tears of laughing so hard). So, for starters, I’m going to try to understand a Brainfuck compiler written in LOLCode. Want to tag along? ;)

Found at http://forum.lolcode.com/viewtopic.php?id=51
  1. HAI
  2. BTW This is a BrainFuck interpreter written in LOLCode
  3. BTW It accepts as input a BF program, followed by a "!", followed  by any input to the BF program.
  4. BTW Since BrainFuck is turing-complete, this proves that LOLCode is too
  5.  
  6. I HAS A INSTRUCTIONS    BTW Array for BF instructions
  7. I HAS A IPTR            BTW Pointer to first empty element in INSTRUCTIONS
  8. IPTR R 0
  9. I HAS A LOOPZ            BTW Array of loop start/end addresses
  10. I HAS A LOOPSTACKZ        BTW Loop stack for building the above two
  11. I HAS A LSPTR            BTW Pointer to first empty element of LOOPSTACKZ
  12. LSPTR R 0
  13.  
  14. BTW Read in BF instructions, terminated with "!"
  15. IM IN YR CODE
  16.   GIMMEH IPTR IN MAH INSTRUCTIONS
  17.  
  18.   BOTH SAEM IPTR IN MAH INSTRUCTIONS AN "[", O RLY?
  19.     YA RLY
  20.       LSPTR IN MAH LOOPSTACKZ R IPTR
  21.       LSPTR R SUM OF LSPTR AN 1
  22.   OIC
  23.  
  24.   BOTH SAEM IPTR IN MAH INSTRUCTIONS AN "]", O RLY?
  25.     YA RLY
  26.       I HAS A STARTPTR
  27.       LSPTR R DIFF OF LSPTR AN 1
  28.       STARTPTR R LSPTR IN MAH LOOPSTACKZ
  29.       STARTPTR IN MAH LOOPZ R IPTR
  30.       IPTR IN MAH LOOPZ R STARTPTR
  31.   OIC
  32.  
  33.   BOTH SAEM IPTR IN MAH INSTRUCTIONS AN "!", O RLY?
  34.     YA RLY
  35.       GTFO
  36.     NO WAI
  37.       IPTR R SUM OF IPTR AN 1
  38.   OIC
  39. IM OUTTA YR CODE
  40.  
  41. BTW Variables for BF's tape
  42. I HAS A LTAPE
  43. I HAS A RTAPE
  44. I HAS A LPTR
  45. LPTR R 0
  46. I HAS A RPTR
  47. RPTR R 0
  48. I HAS A CELL
  49. CELL R 0
  50.  
  51. BTW Reset instruction pointer to start
  52. IPTR R 0
  53.  
  54. BTW Start interpreting
  55. IM IN YR LOOP
  56.   I HAS A THING
  57.   THING R IPTR IN MAH INSTRUCTIONS
  58.  
  59.   BTW Move tape head right
  60.   BOTH SAEM THING AN ">", O RLY?
  61.     YA RLY
  62.       LPTR IN MAH LTAPE R CELL
  63.       LPTR R SUM OF LPTR AN 1
  64.       BOTH SAEM RPTR AN 0, O RLY?
  65.         YA RLY
  66.           CELL R 0
  67.         NO WAI
  68.           RPTR R DIFF OF RPTR AN 1
  69.           CELL R RPTR IN MAH RTAPE
  70.       OIC
  71.   OIC
  72.  
  73.   BTW Move tape head left
  74.   BOTH SAEM THING AN "<", O RLY?
  75.     YA RLY
  76.       RPTR IN MAH RTAPE R CELL
  77.       RPTR R SUM OF RPTR AN 1
  78.       BOTH SAEM LPTR AN 0, O RLY?
  79.         YA RLY
  80.           CELL R 0
  81.         NO WAI
  82.           LPTR R DIFF OF LPTR AN 1
  83.           CELL R LPTR IN MAH LTAPE
  84.       OIC
  85.   OIC
  86.  
  87.   BTW Increment
  88.   BOTH SAEM THING AN "+", O RLY?
  89.     YA RLY
  90.       CELL R SUM OF CELL AN 1
  91.   OIC
  92.  
  93.   BTW Decrement
  94.   BOTH SAEM THING AN "-", O RLY?
  95.     YA RLY
  96.       CELL R DIFF OF CELL AN 1
  97.   OIC
  98.  
  99.   BTW Output produces numbers instead of ASCII characters
  100.   BOTH SAEM THING AN ".", O RLY?
  101.     YA RLY
  102.       VISIBLE CELL!
  103.       VISIBLE " "!
  104.   OIC
  105.  
  106.   BTW Input doesn't work because we can't convert characters to integers
  107.   BTW Oh well, it doesn't stop it being turing complete
  108.  
  109.   BTW Start of loop
  110.   BOTH OF BOTH SAEM THING AN "[" AN BOTH SAEM CELL AN 0, O RLY?
  111.     YA RLY
  112.       IPTR R IPTR IN MAH LOOPZ
  113.   OIC
  114.  
  115.   BTW End of loop
  116.   BOTH OF BOTH SAEM THING AN "]" AN DIFFRINT CELL AN 0, O RLY?
  117.     YA RLY
  118.       IPTR R IPTR IN MAH LOOPZ
  119.   OIC
  120.  
  121.   BTW End of program!
  122.   BOTH SAEM THING AN "!", O RLY?
  123.     YA RLY
  124.       GTFO
  125.   OIC
  126.  
  127.   IPTR R SUM OF IPTR AN 1
  128. IM OUTTA YR LOOP
  129. KTHXBYE

Fun times await.

Tags: , , , , ,

This entry was posted on Friday, July 4th, 2008 at 11:28 am and is filed under Code. You can follow any responses to this entry through the RSS 2.0 feed. You can leave a response, or trackback from your own site.

2 Responses to “Learning a new programming language”

  1. Pedro says:
    September 9, 2008 at 2:33 pm

    LOLZ!

    Reply
  2. Bruno Couto says:
    August 13, 2008 at 2:02 pm

    Hmm, how should i say it… LOL!!!!!!!!!! muahahahah we’re fucking geeks :P

    Reply

Leave a Reply